В контекстное меню можно добавить любой тип элемента управления. Например, в меню можно создать:

• Поле для ввода данных
• Раскрывающийся список
• Кнопку, которая запускает процесс или выполняет задачу
• Подменю

В программе 10 показано, как создать контекстное меню и добавить в него элементы управления.

Программа 10 Создание контекстного меню.

Public Sub BuildShortCutMenu()
     Dim MyShortcutMenu As CommandBar
     Dim cbFormatMenu As CommandBarPopup
     Dim cbFormatColorMenu As CommandBarPopup
     Dim cbFormatPrimaryMenu As CommandBarPopup
     Dim cbFormatPastelMenu As CommandBarPopup
     Dim cbFormatSizeMenu As CommandBarPopup
     Dim cbFormatStyleMenu As CommandBarPopup
     Dim cbEdit As CommandBarComboBox
     Dim cbDropdown As CommandBarComboBox
     Dim cbRed As CommandBarButton
     Dim cbBlue As CommandBarButton
     Dim cbGreen As CommandBarButton
     'Создание строки контекстного меню
     Set MyShortcutMenu = CommandBars.Add(Name:="Shortcut Demo", _
          MenuBar:=False, Temporary:=True, Position:=msoBarPopup)
     Set cbFormatMenu = MyShortcutMenu.Controls.Add _
          (Type:=msoControlPopup)
     cbFormatMenu.Caption = "Формат"
     Set cbEdit = MyShortcutMenu.Controls.Add _
          (Type:=msoControlEdit)
     Set cbDropdown = MyShortcutMenu.Controls.Add _
          (Type:=msoControlDropdown)
     'Задание команд меню Формат
     Set cbFormatColorMenu = cbFormatMenu.Controls.Add _
          (Type:=msoControlPopup)
     cbFormatColorMenu.Caption = "Цвет"
     Set cbFormatSizeMenu = cbFormatMenu.Controls.Add _
          (Type:=msoControlPopup)
     cbFormatSizeMenu.Caption = "Размер"
     Set cbFormatStyleMenu = cbFormatMenu.Controls.Add _
          (Type:=msoControlPopup)
     cbFormatStyleMenu.Caption = "Стиль"
     'Задание команд меню Цвет
     Set cbFormatPrimaryMenu = cbFormatColorMenu.Controls.Add _
          (Type:=msoControlPopup)
     cbFormatPrimaryMenu.Caption = "Фон"
     Set cbFormatPastelMenu = cbFormatColorMenu.Controls.Add _
          (Type:=msoControlPopup)
     cbFormatPastelMenu.Caption = "Черный"
     'Задание команд меню Фон
     Set cbRed = cbFormatPrimaryMenu.Controls.Add _
          (Type:=msoControlButton)
     cbRed.Style = msoButtonCaption
     cbRed.Caption = "Красный"
     Set cbBlue = cbFormatPrimaryMenu.Controls.Add _
          (Type:=msoControlButton)
     cbBlue.Style = msoButtonCaption
     cbBlue.Caption = "Синий"
     Set cbGreen = cbFormatPrimaryMenu.Controls.Add _
          (Type:=msoControlButton)
     cbGreen.Style = msoButtonCaption
     cbGreen.Caption = "Зеленый"
End Sub

Для комментария : kadan@grsu.grodno.by